Cara Backup dan Restore Pengaturan Tampilan Folder di Windows 10

Windows File Explorer mudah dinavigasi dan hadir dengan begitu banyak fitur aksesibilitas yang menarik, salah satunya adalah pengaturan tampilan folder. Anda dapat menyesuaikan folder untuk mewakili jenis file yang mereka simpan.

Misalnya, jika anda memiliki folder dimana anda hanya menyimpan video, anda dapat mengatur folder untuk menampilkan thumbnail video, bukan daftar atau detail file. Anda juga dapat menyesuaikan setiap folder untuk menampilkan ikon medium, large, atau extra-large.

Setelah membuat perubahan ini, anda mungkin ingin membackupnya untuk merestore/memulihkan pengaturan tampilan folder jika anda tidak sengaja mengubahnya atau saat mengintal ulang/mereset Windows anda. Tutorial kali ini akan menunjukkan cara mmbackup dan merestore pengaturan tampilan folder anda dengan menggunakan file batch.

Backup dan Restore Pengaturan Tampilan Folder di Windows 10

Ikuti langkah-langkah di bawah ini untuk membackup dan merestore pengaturan tampilan folder anda di Windows 10.

Kita akan menempuh tiga langkah, jadi sekarang langsung saja ikuti langkah-langkah terperinci yang terlibat dalam menjalankan operasi di atas.

1. Buat File Batch Backup dan Restore

• Klik pada tombol Search dan cari notepad. Pilih aplikasi Notepad dari hasil pencarian untuk meluncurkannya.

• Di notepad masukkan teks berikut di bawah ini.

@ECHO OFF

title Backup and Restore Folder View Settings Tool
:choice
cls
echo.
echo OPTIONS:
echo.
echo 1. Back up your folder view settings.
echo 2. Restore folder view settings from backup.
echo 3. Cancel
echo.
echo.
set /P c=Type the option number you would like to do, and press Enter?
if /I "%c%" EQU "1" goto :verify1
if /I "%c%" EQU "2" goto :verify2
if /I "%c%" EQU "3" exit
goto :choice

:verify1
IF EXIST "%userprofile%\Desktop\Folder View Settings Backup" goto :response1
goto :backup

:response1
echo.
echo.
echo You already have a "Folder View Settings Backup" folder on your desktop.
echo Please move it to another location, and try again.
echo.
pause
goto :choice

:backup
mkdir "%userprofile%\Desktop\Folder View Settings Backup"
REG EXPORT HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\Shell\BagMRU "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\Shell\Bags "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg" /y
REG EXPORT HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg" /y
REG EXPORT "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg" /y
cls
echo.
echo Backup of folder view settings successfully completed.
echo.
pause 
exit

:verify2
IF NOT EXIST "%userprofile%\Desktop\Folder View Settings Backup" goto :response
goto :restore

:response
echo.
echo.
echo You do not have a "Folder View Settings Backup" folder on your desktop.
echo Please place the backup folder on your desktop, and try again.
echo.
pause
goto :choice

:restore 
REG Delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Streams\Defaults" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Microsoft\Windows\Shell\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\Bags" /F
Reg Delete "HKCU\Software\Microsoft\Windows\ShellNoRoam\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" /F
Reg Delete "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" /F

REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_CurrentVersion_Explorer_Streams_Defaults.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_Shell_Bags.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_Bags.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Microsoft_Windows_ShellNoRoam_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_BagMRU.reg"
REG IMPORT "%userprofile%\Desktop\Folder View Settings Backup\HKCU_Software_Classes_LocalSettings_Software_Microsoft_Windows_Shell_Bags.reg"
cls
echo.
echo Backup of folder view settings successfully restored.
echo.
echo Waiting to restart explorer to apply.
echo Your screen will flash as explorer is restarted.
echo.
echo.
pause
taskkill /f /im explorer.exe
start explorer.exe 
exit

• Anda dapat mengcopy dan mempaste teks di atas ke dalam notepad. Selanjutnya, klik File dan pilih Save as. Beri nama file diikuti dengan ekstensi .bat dan klik Save untuk menyimpan file di desktop anda.

File yang disimpan dalam ekstensi .bat adalah file batch dan jika dilakukan dengan benar, anda dapat menjalankan perintah di system Windows.

2. Buka Blokir File .bat

Setelah berhasil menyimpan file yang baru dibuat sebagai file .bat, Windows mungkin memblokirnya. Untuk menjalankan file ini, anda harus membebaskannya terlebih dahulu dari blokiran.

• Untuk melakukan ini, klik kanan pada file dan pilih Properties dari menu konteks.

• Di jendela Properties, alihkan ke tab General dan berikan ceklist pada kotak Unblock di bagian bawah jendela. Selanjutnya klik OK untuk membuka blokir file batch.

Catatan: Jika kotak ceklist Unblock tidak ada di properties anda, itu berarti Windows tidak memblokir file dan anda dapat melanjutkan ke langkah berikutnya.

3. Jalankan File .bat

Setelah membuka blokir file .bat, anda sekarang siap melakukannya. Anda dapat menjalankan file .bat dengan mengklik dobel di atasnya. Menjalankan file batch akan membuka jendela Command Prompt yang menampilkan opsi berikut ini:

• Back up your folder view settings.

• Restore folder view settings from backup.

• Cancel.

Untuk membuat backup pengaturan tampilan folder anda, tekan 1 dan tekan tombol Enter. Jika anda ingin restore/mengembalikan pengaturan tampilan folder anda, maka tekan 2 dan tekan Enter. Atau tekan 3 untuk membatalkan operasi.

Anda juga dapat membuat file batch untuk penggunaan yang lainnya. Baca tutorial saya tentang cara memindahkan banyak file menggunakan file batch di Windows 10 atau cara mengganti nama file dengan batch di Windows.

Sekian tutorial kali ini, semoga bermanfaat untuk anda. Jangan lupa tinggalkan komentar anda dibawah ini untuk berbagi pengalaman dalam mengikuti tutorial ini. Terimakasih dan GBU. BERSATU LAWAN COVID-19!!

source https://neinfoku.blogspot.com/2020/12/cara-backup-dan-restore-pengaturan.html